嵌入式 > 嵌入式开发 > 详情

FS2410 开发板上的内存搬移实验

发布时间:2020-08-24 发布时间:
|
一、目的

通过将 Nand Flash 前 4K 代码搬移到 SDRAM 中,了解如何初始化并使用 ARM 的内存,

为编写 ARM bootloader 和搬移内核到内存作准备。

二、代码

关于如何建立开发环境,在我的前一篇随笔(FS2401 发光二极管循环点亮)里有介绍, 请

参考。要初始化并使用内存需要了解一些很锁碎的细节,上来就讲这些知识点未免生涩,不

如在代码中穿插讲解来的直接。

@ 文件 head.s

@ 作用: 关闭看门狗、设置内存、向 SDRAM 搬移 Nand Flash 的前 4K 代码、设置堆栈、

@ 调用已经搬移到 SDRAM 的 main 函数

.text

.global _start

_start:

ldr r0, =0x53000000 @ Close watch-dog

mov r1, #0x0

str r1, [r0]

bl memory_setup@ Initialize memory setting

bl copy_block_to_sdram @ Move code to SDRAM

ldr sp, =0x34000000 @ Set stack pointer

ldr pc, =main @ call main in SDRAM

halt_loop:

b halt_loop

copy_block_to_sdram:

mov r0, #0x0

mov r1, #0x30000000

mov r2, #4096

copy_loop:

ldmia r0!, {r3-r10}

stmia r1!, {r3-r10}

cmp r0, r2

blo copy_loop

注:看门狗(Watch Dog Timer,简称为WDT)技术就是最常见的抗干扰技术,实际上是一个

可清零的定时计数器

@ 文件 memory.s

@ 初始化内存控制寄存器

.global memory_setup@ 导出 memory_setup, 使其对链接器可见

memory_setup:

mov r1, #0x48000000 @ BWSCON 内存控制寄存器地址

adrl r2, mem_cfg_val

add r3, r1, #13*4

1:

@ write initial values to registers

ldr r4, [r2], #4

str r4, [r1], #4

cmp r1, r3

bne 1b

mov pc, lr

.align 4

mem_cfg_val:

.long 0x22111110 @ BWSCON

.long 0x00000700 @ BANKCON0

.long 0x00000700 @ BANKCON1

.long 0x00000700 @ BANKCON2

.long 0x00000700 @ BANKCON3

.long 0x00000700 @ BANKCON4

.long 0x00000700 @ BANKCON5

.long 0x00018005 @ BANKCON6

.long 0x00018005 @ BANKCON7 9bit

.long 0x008e07a3 @ REFRESH

.long 0x000000b2 @ BANKSIZE

.long 0x00000030 @ MRSRB6

.long 0x00000030 @ MRSRB7

注: 要理解这里的寄存器设置需要看手册和资料, 这里简单介绍一下:

1.BWSCON:对应BANK0-BANK7,每BANK使用4位。这4位分别表示:

a.STx:启动/禁止SDRAM的数据掩码引脚,对SDRAM,此位为0;对SRAM,此位为1

b.WSx:是否使用存储器的WAIT信号,通常设为0

c.DWx:使用两位来设置存储器的位宽:00-8位,01-16位,10-32位,11-保留。

d.比较特殊的是BANK0对应的4位,它们由硬件跳线决定,只读。

e.对于本开发板,使用两片容量为32Mbyte、位宽为16的SDRAM组成容量为64Mbyte、

位宽为32的存储器,所以其BWSCON相应位为:0010。对于本开发板,BWSCON可设为

0x22111110:其实我们只需要将BANK6对应的4位设为0010即可,其它的是什么值没

什么影响,这个值是参考手册上给出的。

2.BANKCON0-BANKCON5:我们没用到,使用默认值0x00000700即可

3.BANKCON6-BANKCON7:设为0x00018005

在8个BANK中,只有BANK6和BANK7可以使用SRAM或SDRAM,与BANKCON0-5有点不同:

a.MT([16:15]):用于设置本BANK外接的是SRAM还是SDRAM:SRAM-0b00,SDRAM-0b11

b.当MT=0b11时,还需要设置两个参数:

Trcd([3:2]):RAS to CAS delay,设为推荐值0b01

SCAN([1:0]):SDRAM的列地址位数,本开发板的SDRAM列地址位数为9,所以SCAN=0b01

4.REFRESH(SDRAM refresh control register):

其中R_CNT用于控制SDRAM的刷新周期,占用REFRESH寄存器的[10:0]位,它的取值可

如下计算(SDRAM时钟频率就是HCLK):

R_CNT = 2^11 + 1 – SDRAM时钟频率(MHz) * SDRAM刷新周期(uS)

在未使用PLL时,SDRAM时钟频率等于晶振频率12MHz;SDRAM的刷新周期在SDRAM的数

据手册上有标明,在本开发板使用的SDRAM HY57V561620CT-H的数据手册上,可看见

这么一行“8192 refresh cycles / 64ms”:所以,刷新周期=64ms/8192 = 7.8125 uS。

对于本实验,R_CNT = 2^11 + 1 – 12 * 7.8125 = 1955

REFRESH=0x008e0000 + 1955 = 0x008e07a3

5.BANKSIZE:0x000000b2

位[7]=1:Enable burst operation

位[5]=1:SDRAM power down mode enable

位[4]=1:SCLK is active only during the access (recommended)

位[2:1]=010 BANK6、BANK7对应的地址空间: 010-128M/128M, 001-64M/64M

6.MRSRB6、MRSRB7:0x00000030

能让我们修改的只有位[6:4](CL),SDRAM HY57V561620CT-H不支持CL=1的情况,所以

位[6:4]取值为010(CL=2)或011(CL=3)

/* 文件 sdram.c */

/* 作用 循环点亮开发板上的 D9、D10、D11、D12 四个发光二极管 */

#define GPFCON (*(volatile unsigned long *)0x56000050) /* GPFCON 端口地址为0x56000050 */

#define GPFDAT (*(volatile unsigned long *)0x56000054) /* GPFDAT 端口地址为0x56000054 */

int main()

{

int i,j;

while(1) {

for (i = 0; i <4; ++i) {

GPFCON = 0x1<

GPFDAT = 0x0;/* 篇随笔(FS2401 发光二极管循环点亮) */

/* 里有介绍*/

// for delay

for(j=0;j<50000;++j) ;

}

}

}

# Makefile

# 编译上述三个代码文件, 并链接生成的目标文件,

# 再将目标文件(ELF格式)转换成二进制格式文件

sdram:head.s memory.s sdram.c

arm-linux-gcc -c -o head.o head.s

arm-linux-gcc -c -o memory.o memory.s

arm-linux-gcc -c -o sdram.o sdram.c

# -Ttext 0x30000000 会使目标文件里 ldr pc, =main 指令里的 pc 加上

# 0x30000000 这个基地址,而 #0x30000000 正是我们要将代码搬到 SDRAM 的

# 起始地址, 更多细节请参考 arm-linux-ld -Ttext 的用法

arm-linux-ld -Ttext 0x30000000 head.o memory.o sdram.o -o sdram_tmp.o

arm-linux-objcopy -O binary -S sdram_tmp.o sdram

clean:

rm -f *.o

rm -f sdram

三、编译、烧写、测试

Make 一下就会生成我们要的文件 sdram, 将其通过 JTAG 烧入 Nand Flash 即可,Reset

一下开发板, 欣赏您的实验成果吧



『本文转载自网络,版权归原作者所有,如有侵权请联系删除』

热门文章 更多
定时器CTC模式的测试