汇编编程：矩阵键盘控制数码管切换显示0~F。

下面是电路图。要求16个键按下能显示0~F字样。

看到这样的电路和程序，不由得想起初学单片机时情景。

十几年前，是一本北航的书，里面就是这样的程序。

后来又看过几本，里面也有雷同的程序。

其实，该程序编写的很滥。

它把行列号码，算的很清。还特意弄成几个分支。

换下一行时，行号就要分别存入 00H、08H、10H、18H。

想法也太笨了，其实，只要加上 8，就可以编写成循环程序了。

程序中，还有很多应该简化的地方。

这程序学起来，的确浪费了我不少的时间。

根据题目中的电路和程序，做而论道改写的程序如下。

;

    ORG   0000H

    SJMP  START

    ORG   0030H

;--------------------------------------

DUMA:

    DB    3FH, 06H, 5BH, 4FH, 66H, 6DH, 7DH, 07H //共阴段码

    DB    7FH, 6FH, 77H, 7CH, 39H, 5EH, 79H, 71H

;--------------------------------------

START:

    MOV   DPTR, #7F03H  //8255初始化

    MOV   A, #90H

    MOVX  @DPTR, A

    MOV   A, #16

;--------------------------------------

KEY1:

    ACALL KS1           //判断有无键按下, 返回PA口状态存放在A中

    JZ    KEY1          //无则返回

    ACALL DELAY         //调用延时子程序

    ACALL KS1           //再次判断有无键按下

    JZ    KEY1          //无则返回

;

    MOV   R2, #0FEH     //初始列扫描字

    MOV   R3, #8        //检查8次

    MOV   R4, #0        //初始键号

LK4:

    MOV   DPTR, #7F01H  //指向PB口

    MOV   A, R2

    MOVX  @DPTR, A

    MOV   DPTR, #7F00H  //指向PA口

    MOVX  A, @DPTR

    JNB   ACC.0, LK3

    INC   R4

    JNB   ACC.1, LK3

    INC   R4

    MOV   A, R2

    RL    A             //无则左移一位列扫描字, 继续判断下一列

    MOV   R2, A

    DJNZ  R3, LK4

LK3:

    ACALL KS1          

    JNZ   LK3           //判断按下的键有没有弹起, 无则原地等待继续判断

;

    MOV   A, R4         //键号放于A中

    MOV   DPTR, #0030H  //指向段码表首址

    MOVC  A, @A + DPTR  //键号转成相应的段码

    MOV   DPTR, #7F02H  //指向PC口

    MOVX  @DPTR, A      //数码管显示

;

    SJMP  KEY1

;--------------------------------------

KS1:

    MOV   DPTR, #7F01H  //指向PB口

    MOV   A, #0

    MOVX  @DPTR, A

    MOV   DPTR, #7F00H  //指向PA口

    MOVX  A, @DPTR

    CPL   A

    ANL   A, #03H

    RET                 //返回PA口数据存放在A中, 若有键按下, 则A不等于零

;--------------------------------------

DELAY:                  //延时子程序, 约10ms

    MOV   R7, #20

D1: DJNZ  R6, $

    DJNZ  R7, D1

    RET

END

;======================================

本程序运行的仿真截图，可见前面的插图。

题目中的电路，仅仅使用了一个数码管。这和实用的场合，还有差距。

如果使用动态显示的方法，驱动多位数码管，那么，矩阵键盘的规模，就可以再扩大一些。

而做而论道在这里给出的程序，却不用增加很多，仅仅再添上三、五行即可够用。